;:poke1,55:sys36864
	;.opt oo
	*= $c000
tmp	=2
strout	=$ab1e
konf	=1
alt	=42115
altl	=$a71a
syntax	=44808
outmem	=42037
illquan	=$b248
error	=42039
	lda konf
	and #3
	cmp #3
	bcc fertig
	ldy #0
	sty tmp
	lda #160
	sta tmp+1
	ldx #32
copyrom	lda (tmp),y
	sta (tmp),y
	iny
	bne copyrom
	inc tmp+1
	dex
	bne copyrom
	ldx #0
copyp	lda rompos,x
	sta tmp
	lda rompos+1,x
	sta tmp+1
	beq fertig
	ldy #0
	lda #76
	sta (tmp),y
	lda rampos,x
	iny
	sta (tmp),y
	lda rampos+1,x
	iny
	sta (tmp),y
	inx
	inx
	bne copyp
fertig	lda konf
	and #252
	ora #2
	sta konf
	lda #5
	sta $b78f
	lda #144
	sta $a740
	lda #1
	sta $a369
	lda #<hi
	ldy #>hi
	jmp strout
hi	.byte "\x93\x11   ***  error analyzer v2.0  c64  ***"
	.byt 13
	.byte "\x11 by nikolaus heusler  (c) nh-250490-arr"
	.byt 13,0
rompos	.word $a471,$a6d4,$a851,$b0c8,$a3fb
	.word $aeff,$b7a4,$a807,$ad9b,$ab02,$b1c9,$b1bb
	.word $b7f7,$adcb,$b441,$b9f1,$ab5f,$a953,$a97b
	.word $aa24,$b09c,$a80b,$b138,0
rampos	.word listp,cache,stopf,prozent,stack
	.word expect,less,further,type,bracket,bereich,posi
	.word intgr,twice,extra2,nega,geterr,on,list
	.word tei,let,let,rvar
t1	.byte "% variables disallowed"
	brk
t2	.byte "stack overflow"
	brk
t3	.byte " expected"
	brk
t4	.byte "must be 255 or less"
	brk
t5	.byte "extra characters"
	brk
t6	.byte "string expected"
	brk
t7	.byte "numeric type expected"
	brk
t8	.byte "missing )"
	brk
t9	.byte "must be -32768 to 32767"
	brk
ta	.byte "must be positive"
	brk
tb	.byte "must be 0 to 65535"
	brk
tc	.byte "operator used twice"
	brk
td	.byte "number expected"
	brk
te	.byte "goto or gosub expected"
	brk
tf	.byte "must be 63999 or less"
	brk
tg	.byte "ti$ format wrong"
	brk
th	.byte "letter expected"
	brk
ti	.byte "reserved variable"
	brk
listp	jsr $bdc2
	lda 122
	sta mem
	lda 123
	sta mem+1
	lda #<neu
	sta 770
	lda #>neu
	sta 771
	jmp $a474
mem	.word 0
mm	brk
merk	brk
flag	brk
neu	lda #<alt
	sta 770
	lda #>alt
	sta 771
	lda #"\x91"
	jsr $ffd2
	jsr $ffd2
	lda #0
	sta 211
	lda #<listneu
	sta 774
	lda #>listneu
	sta 775
	lda #96
	sta $a714
	lda 57
	sta 20
	lda 58
	sta 21
	jsr $a613
	lda #0
	sta flag
	jsr $a6c9
	jsr $e701
	lda merk
	sta 211
	lda #76
	sta $a714
	lda #<altl
	sta 774
	lda #>altl
	sta 775
	lda #1
	sta 198
	lda #"\x11"
	sta 631
	lda #"\x91"
	jsr $ffd2
	jmp (770)
listneu	php
	pha
	tya
	clc
	adc $5f
	pha
	lda $60
	adc #0
	sta mm
	pla
	cmp mem
	bne aeae
	lda mm
	cmp mem+1
	bne aeae
	lda 211
	sta merk
	inc flag
aeae	pla
	plp
	jmp altl
stopf	jsr strout
	ldy 58
	iny
	beq l3
	jsr 48578
l3	jmp 42100
cache	lda flag
	bne wars
	lda 211
	sta merk
wars	jsr $aad7
	jmp $a6d7
init	jsr $ffcc
	lda #0
	sta 19
	jsr $aad7
	inc 199
	rts
prozent	lda 16
	bne lab3
	jmp 45260
lab3	jsr init
	lda #<t1
	ldy #>t1
syn	jsr strout
	jmp syntax
stack	asl
	adc #58
	bcs l8
	sta 34
	tsx
	cpx 34
	bcc l8
	rts
l8	jsr init
	lda #<t2
	ldy #>t2
	jsr strout
	jmp outmem
expect	ldy #0
	cmp (122),y
	bne la3
	jmp 115
la3	pha
	jsr init
	pla
	cmp #178
	beq est
	cmp #$a7
	beq tthen
	cmp #$a4
	beq tgo
	cmp #165
	bne out
	lda #"f"
	jsr $ffd2
	lda #"n"
	.byt $2c
est	lda #"="
out	jsr $ffd2
	lda #<t3
	ldy #>t3
xsyn	bne syn
tthen	lda #"t"
	jsr $ffd2
	lda #"h"
	jsr $ffd2
	lda #"e"
	jsr $ffd2
	lda #"n"
	bne out
tgo	lda #"t"
	jsr $ffd2
	lda #"o"
	bne out
less	ldx $64
	bne wrong
	jmp $b7a8
wrong	jsr init
	lda #<t4
	ldy #>t4
ill	jsr strout
	jmp illquan
further	cmp #58
	bne extra
	jmp $a7e1
extra	jsr init
	lda #<t5
	ldy #>t5
qsyn	bne xsyn
extra2	jsr $79
	bne extra
	jmp $b449
type	php
	jsr init
	plp
	bcc numeric
	lda #<t6
	ldy #>t6
	bne stout
numeric	lda #<t7
	ldy #>t7
stout	jsr strout
	ldx #22
	jmp error
bracket	cmp #")"
	bne neinkl
	jmp 43782
neinkl	jsr init
	lda #<t8
	ldy #>t8
	bne qsyn
bereich	jsr 48219
	bne nix
	jmp 48283
nix	jsr init
	lda #<t9
	ldy #>t9
	bne ill
posi	lda $66
	bmi nega
	jmp $b1bf
nega	jsr init
	lda #<ta
	ldy #>ta
	bne ill
intgr	lda $66
	bmi fal
	lda $61
	cmp #$91
	bcs fal
	jmp $b801
fal	jsr init
	lda #<tb
	ldy #>tb
	bne ill
twice	cmp $4d
	bcc eheh
	jmp $adcf
eheh	jsr init
	lda #<tc
	ldy #>tc
qqsyn	bne qsyn
geterr	jsr init
	lda #<td
	ldy #>td
	bne qqsyn
on	cmp #$89
	bne fehlt
	jmp $a957
fehlt	jsr init
	lda #<te
	ldy #>te
	bne qqsyn
list	cmp #$19
	bcs great
	jmp $a97f
great	jsr init
	lda #<tf
	ldy #>tf
	bne qqsyn
tei	jsr init
	lda #<tg
	ldy #>tg
	jmp ill
let	jsr init
	lda #<th
	ldy #>th
	bne qqsyn
rvar	jsr init
	lda #<ti
	ldy #>ti
	bne qqsyn